libpam_1.7.1.bb 6.7 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172
  1. DISABLE_STATIC = ""
  2. SUMMARY = "Linux-PAM (Pluggable Authentication Modules)"
  3. DESCRIPTION = "Linux-PAM (Pluggable Authentication Modules for Linux), a flexible mechanism for authenticating users"
  4. HOMEPAGE = "https://fedorahosted.org/linux-pam/"
  5. BUGTRACKER = "https://fedorahosted.org/linux-pam/newticket"
  6. SECTION = "base"
  7. # PAM is dual licensed under GPL and BSD.
  8. # /etc/pam.d comes from Debian libpam-runtime in 2009-11 (at that time
  9. # libpam-runtime-1.0.1 is GPL-2.0-or-later), by openembedded
  10. LICENSE = "GPL-2.0-or-later | BSD-3-Clause"
  11. LIC_FILES_CHKSUM = "file://COPYING;md5=7eb5c1bf854e8881005d673599ee74d3 \
  12. file://libpamc/License;md5=a4da476a14c093fdc73be3c3c9ba8fb3 \
  13. "
  14. SRC_URI = "${GITHUB_BASE_URI}/download/v${PV}/Linux-PAM-${PV}.tar.xz \
  15. file://99_pam \
  16. file://pam.d/common-account \
  17. file://pam.d/common-auth \
  18. file://pam.d/common-password \
  19. file://pam.d/common-session \
  20. file://pam.d/common-session-noninteractive \
  21. file://pam.d/other \
  22. file://run-ptest \
  23. file://pam-volatiles.conf \
  24. "
  25. SRC_URI[sha256sum] = "21dbcec6e01dd578f14789eac9024a18941e6f2702a05cf91b28c232eeb26ab0"
  26. DEPENDS = "bison-native flex-native libxml2-native virtual/crypt"
  27. EXTRA_OEMESON = "-Ddocs=disabled -Dsecuredir=${base_libdir}/security"
  28. LDFLAGS += "${@bb.utils.contains('DISTRO_FEATURES', 'ld-is-lld', ' -Wl,--undefined-version', '', d)}"
  29. S = "${UNPACKDIR}/Linux-PAM-${PV}"
  30. inherit meson gettext pkgconfig systemd ptest github-releases
  31. PACKAGECONFIG ??= ""
  32. PACKAGECONFIG[audit] = "-Daudit=enabled,-Daudit=disabled,audit,"
  33. PACKAGECONFIG[userdb] = "-Dpam_userdb=enabled -Ddb=gdbm,-Dpam_userdb=disabled,gdbm,"
  34. PACKAGECONFIG[selinux] = "-Dselinux=enabled,-Dselinux=disabled,libselinux,"
  35. PACKAGES += "${PN}-runtime ${PN}-xtests"
  36. FILES:${PN} = " \
  37. ${libdir}/lib*${SOLIBS} \
  38. ${nonarch_libdir}/tmpfiles.d/*.conf \
  39. "
  40. FILES:${PN}-dev += "${base_libdir}/security/*.la ${libdir}/*.la ${libdir}/lib*${SOLIBSDEV}"
  41. FILES:${PN}-runtime = "${sysconfdir} ${sbindir} ${nonarch_libdir}/systemd/system"
  42. FILES:${PN}-xtests = "${datadir}/Linux-PAM/xtests"
  43. # libpam installs /etc/environment for use with the pam_env plugin. Make sure it is
  44. # packaged with the pam-plugin-env package to avoid breaking installations which
  45. # install that file via other packages
  46. FILES:pam-plugin-env = "${sysconfdir}/environment"
  47. PACKAGES_DYNAMIC += "^${MLPREFIX}pam-plugin-.*"
  48. def get_multilib_bit(d):
  49. baselib = d.getVar('baselib') or ''
  50. return baselib.replace('lib', '')
  51. libpam_suffix = "suffix${@get_multilib_bit(d)}"
  52. RPROVIDES:${PN} += "${PN}-${libpam_suffix}"
  53. RPROVIDES:${PN}-runtime += "${PN}-runtime-${libpam_suffix}"
  54. RDEPENDS:${PN}-runtime = "${PN}-${libpam_suffix} \
  55. ${MLPREFIX}pam-plugin-deny-${libpam_suffix} \
  56. ${MLPREFIX}pam-plugin-permit-${libpam_suffix} \
  57. ${MLPREFIX}pam-plugin-warn-${libpam_suffix} \
  58. ${MLPREFIX}pam-plugin-unix-${libpam_suffix} \
  59. ${@bb.utils.contains('PACKAGECONFIG', 'selinux', '${MLPREFIX}pam-plugin-selinux-${libpam_suffix}', '', d)} \
  60. "
  61. RDEPENDS:${PN}-xtests = "${PN}-${libpam_suffix} \
  62. ${MLPREFIX}pam-plugin-access-${libpam_suffix} \
  63. ${MLPREFIX}pam-plugin-debug-${libpam_suffix} \
  64. ${MLPREFIX}pam-plugin-pwhistory-${libpam_suffix} \
  65. ${MLPREFIX}pam-plugin-succeed-if-${libpam_suffix} \
  66. ${MLPREFIX}pam-plugin-time-${libpam_suffix} \
  67. bash coreutils"
  68. # FIXME: Native suffix breaks here, disable it for now
  69. RRECOMMENDS:${PN} = "${PN}-runtime-${libpam_suffix}"
  70. RRECOMMENDS:${PN}:class-native = ""
  71. python populate_packages:prepend () {
  72. def pam_plugin_hook(file, pkg, pattern, format, basename):
  73. pn = d.getVar('PN')
  74. libpam_suffix = d.getVar('libpam_suffix')
  75. rdeps = d.getVar('RDEPENDS:' + pkg)
  76. if rdeps:
  77. rdeps = rdeps + " " + pn + "-" + libpam_suffix
  78. else:
  79. rdeps = pn + "-" + libpam_suffix
  80. d.setVar('RDEPENDS:' + pkg, rdeps)
  81. provides = d.getVar('RPROVIDES:' + pkg)
  82. if provides:
  83. provides = provides + " " + pkg + "-" + libpam_suffix
  84. else:
  85. provides = pkg + "-" + libpam_suffix
  86. d.setVar('RPROVIDES:' + pkg, provides)
  87. mlprefix = d.getVar('MLPREFIX') or ''
  88. dvar = d.expand('${WORKDIR}/package')
  89. pam_libdir = d.expand('${base_libdir}/security')
  90. pam_sbindir = d.expand('${sbindir}')
  91. pam_filterdir = d.expand('${base_libdir}/security/pam_filter')
  92. pam_pkgname = mlprefix + 'pam-plugin%s'
  93. do_split_packages(d, pam_libdir, r'^pam(.*)\.so$', pam_pkgname,
  94. 'PAM plugin for %s', hook=pam_plugin_hook, extra_depends='', prepend=True)
  95. do_split_packages(d, pam_filterdir, r'^(.*)$', 'pam-filter-%s', 'PAM filter for %s', extra_depends='')
  96. }
  97. do_install:append() {
  98. # don't install /var/run when populating rootfs. Do it through volatile
  99. rm -rf ${D}${localstatedir}
  100. if ${@bb.utils.contains('DISTRO_FEATURES','sysvinit','false','true',d)}; then
  101. rm -rf ${D}${sysconfdir}/init.d/
  102. rm -rf ${D}${sysconfdir}/rc*
  103. install -d ${D}${nonarch_libdir}/tmpfiles.d
  104. install -m 0644 ${UNPACKDIR}/pam-volatiles.conf \
  105. ${D}${nonarch_libdir}/tmpfiles.d/pam.conf
  106. else
  107. install -d ${D}${sysconfdir}/default/volatiles
  108. install -m 0644 ${UNPACKDIR}/99_pam \
  109. ${D}${sysconfdir}/default/volatiles/
  110. fi
  111. install -d ${D}${sysconfdir}/pam.d/
  112. install -m 0644 ${UNPACKDIR}/pam.d/* ${D}${sysconfdir}/pam.d/
  113. # The lsb requires unix_chkpwd has setuid permission
  114. chmod 4755 ${D}${sbindir}/unix_chkpwd
  115. if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
  116. echo "session optional pam_systemd.so" >> ${D}${sysconfdir}/pam.d/common-session
  117. fi
  118. }
  119. do_install_ptest() {
  120. mkdir -p ${D}${PTEST_PATH}/tests
  121. find ${B}/tests -maxdepth 1 -type f -exec cp {} ${D}${PTEST_PATH}/tests \;
  122. install -m 0644 ${S}/tests/confdir ${D}${PTEST_PATH}/tests
  123. }
  124. pkg_postinst:${PN}() {
  125. if [ -z "$D" ] && [ -e /etc/init.d/populate-volatile.sh ] ; then
  126. /etc/init.d/populate-volatile.sh update
  127. fi
  128. }
  129. inherit features_check
  130. ANY_OF_DISTRO_FEATURES = "pam systemd"
  131. BBCLASSEXTEND = "nativesdk native"
  132. CONFFILES:${PN}-runtime += "${sysconfdir}/pam.d/common-session"
  133. CONFFILES:${PN}-runtime += "${sysconfdir}/pam.d/common-auth"
  134. CONFFILES:${PN}-runtime += "${sysconfdir}/pam.d/common-password"
  135. CONFFILES:${PN}-runtime += "${sysconfdir}/pam.d/common-session-noninteractive"
  136. CONFFILES:${PN}-runtime += "${sysconfdir}/pam.d/common-account"
  137. CONFFILES:${PN}-runtime += "${sysconfdir}/security/limits.conf"
  138. GITHUB_BASE_URI = "https://github.com/linux-pam/linux-pam/releases"
  139. CVE_PRODUCT = "linux-pam"