gtk4_4.18.6.bb 4.9 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135
  1. SUMMARY = "Multi-platform toolkit for creating GUIs"
  2. DESCRIPTION = "GTK is a multi-platform toolkit for creating graphical user interfaces. Offering a complete \
  3. set of widgets, GTK is suitable for projects ranging from small one-off projects to complete application suites."
  4. HOMEPAGE = "http://www.gtk.org"
  5. BUGTRACKER = "https://gitlab.gnome.org/GNOME/gtk/-/issues/"
  6. SECTION = "libs"
  7. DEPENDS = " \
  8. atk \
  9. cairo \
  10. fribidi \
  11. gdk-pixbuf \
  12. gdk-pixbuf-native \
  13. glib-2.0 \
  14. graphene \
  15. harfbuzz \
  16. jpeg \
  17. libdrm \
  18. libepoxy \
  19. libpng \
  20. librsvg \
  21. libxkbcommon \
  22. pango \
  23. python3-docutils-native \
  24. tiff \
  25. "
  26. LICENSE = "LGPL-2.0-only & LGPL-2.0-or-later & LGPL-2.1-or-later"
  27. LIC_FILES_CHKSUM = " \
  28. file://COPYING;md5=5f30f0716dfdd0d91eb439ebec522ec2 \
  29. file://gtk/gtk.h;endline=25;md5=61900d77e8d5bc67cf15ad93de9a3490 \
  30. file://gdk/gdk.h;endline=25;md5=a0fb26c1f6b94e66d148279e192c333f \
  31. file://tests/testgtk.c;endline=25;md5=49d06770681b8322466b52ed19d29fb2 \
  32. "
  33. MAJ_VER = "${@oe.utils.trim_version("${PV}", 2)}"
  34. UPSTREAM_CHECK_REGEX = "gtk-(?P<pver>\d+\.(\d*[02468])+(\.\d+)+)\.tar.xz"
  35. SRC_URI = "http://ftp.gnome.org/pub/gnome/sources/gtk/${MAJ_VER}/gtk-${PV}.tar.xz"
  36. SRC_URI[sha256sum] = "e1817c650ddc3261f9a8345b3b22a26a5d80af154630dedc03cc7becefffd0fa"
  37. S = "${UNPACKDIR}/gtk-${PV}"
  38. CVE_PRODUCT = "gnome:gtk"
  39. inherit meson gettext pkgconfig gi-docgen update-alternatives gsettings features_check gobject-introspection
  40. # TBD: nativesdk
  41. # gobject-introspection.bbclass pins introspection off for nativesk. As long as
  42. # we do not remove this wisdom or hack gtk4, it is not possible to build
  43. # nativesdk-gtk4
  44. BBCLASSEXTEND = "native"
  45. GSETTINGS_PACKAGE:class-native = ""
  46. ANY_OF_DISTRO_FEATURES = "${GTK3DISTROFEATURES}"
  47. REQUIRED_DISTRO_FEATURES = "opengl"
  48. GIDOCGEN_MESON_OPTION = "documentation"
  49. GIR_MESON_ENABLE_FLAG = 'enabled'
  50. GIR_MESON_DISABLE_FLAG = 'disabled'
  51. EXTRA_OEMESON = " -Dbuild-tests=false -Dbuild-testsuite=false -Dbuild-demos=false"
  52. PACKAGECONFIG ??= "gstreamer ${@bb.utils.filter('DISTRO_FEATURES', 'wayland x11 vulkan', d)}"
  53. PACKAGECONFIG:class-native = "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)}"
  54. PACKAGECONFIG:class-nativesdk = "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)}"
  55. PACKAGECONFIG[x11] = "-Dx11-backend=true,-Dx11-backend=false,at-spi2-atk fontconfig libx11 libxext libxcursor libxi libxdamage libxrandr libxrender libxcomposite libxfixes xinerama"
  56. PACKAGECONFIG[wayland] = "-Dwayland-backend=true,-Dwayland-backend=false,wayland wayland-protocols virtual/egl virtual/libgles2 wayland-native"
  57. PACKAGECONFIG[cloudproviders] = "-Dcloudproviders=enabled,-Dcloudproviders=disabled,libcloudproviders"
  58. PACKAGECONFIG[cups] = "-Dprint-cups=enabled,-Dprint-cups=disabled,cups,cups gtk4-printbackend-cups"
  59. PACKAGECONFIG[colord] = "-Dcolord=enabled,-Dcolord=disabled,colord"
  60. PACKAGECONFIG[iso-codes] = ",,iso-codes,iso-codes"
  61. # gtk4 wants gstreamer-player-1.0 -> gstreamer1.0-plugins-bad
  62. PACKAGECONFIG[gstreamer] = "-Dmedia-gstreamer=enabled,-Dmedia-gstreamer=disabled,gstreamer1.0-plugins-bad"
  63. PACKAGECONFIG[tracker] = "-Dtracker=enabled,-Dtracker=disabled,tinysparql,localsearch"
  64. PACKAGECONFIG[vulkan] = "-Dvulkan=enabled,-Dvulkan=disabled, vulkan-loader vulkan-headers shaderc-native"
  65. # Disable int-conversion warning as error until [1] is fixed
  66. # [1] https://gitlab.gnome.org/GNOME/gtk/-/issues/6033
  67. CFLAGS += "-Wno-error=int-conversion"
  68. LIBV = "4.0.0"
  69. FILES:${PN}:append = " \
  70. ${datadir}/glib-2.0/schemas/ \
  71. ${datadir}/gtk-4.0/emoji/ \
  72. ${datadir}/metainfo/ \
  73. ${datadir}/icons/hicolor/*/apps/org.gtk.PrintEditor4*.* \
  74. ${libdir}/gtk-4.0/${LIBV}/media \
  75. ${bindir}/gtk4-update-icon-cache \
  76. ${bindir}/gtk4-launch \
  77. "
  78. FILES:${PN}-dev += " \
  79. ${datadir}/gtk-4.0/gtk4builder.rng \
  80. ${datadir}/gtk-4.0/include \
  81. ${datadir}/gtk-4.0/valgrind \
  82. ${datadir}/gettext/its \
  83. ${bindir}/gtk4-builder-tool \
  84. ${bindir}/gtk4-encode-symbolic-svg \
  85. ${bindir}/gtk4-query-settings \
  86. "
  87. GTKBASE_RRECOMMENDS ?= " \
  88. liberation-fonts \
  89. gdk-pixbuf-loader-png \
  90. gdk-pixbuf-loader-jpeg \
  91. gdk-pixbuf-loader-gif \
  92. gdk-pixbuf-loader-xpm \
  93. shared-mime-info \
  94. adwaita-icon-theme-symbolic \
  95. "
  96. GTKBASE_RRECOMMENDS:class-native ?= ""
  97. GTKGLIBC_RRECOMMENDS ?= "${GTKBASE_RRECOMMENDS} glibc-gconv-iso8859-1"
  98. RRECOMMENDS:${PN} = "${GTKBASE_RRECOMMENDS}"
  99. RRECOMMENDS:${PN}:libc-glibc = "${GTKGLIBC_RRECOMMENDS}"
  100. RDEPENDS:${PN}-dev += "${@bb.utils.contains("PACKAGECONFIG", "wayland", "wayland-protocols", "", d)}"
  101. PACKAGES_DYNAMIC += "^gtk4-printbackend-.*"
  102. python populate_packages:prepend () {
  103. import os.path
  104. gtk_libdir = d.expand('${libdir}/gtk-4.0/${LIBV}')
  105. printmodules_root = os.path.join(gtk_libdir, 'printbackends');
  106. do_split_packages(d, printmodules_root, r'^libprintbackend-(.*)\.so$', 'gtk4-printbackend-%s', 'GTK printbackend module for %s')
  107. if (d.getVar('DEBIAN_NAMES')):
  108. d.setVar(d.expand('PKG:${PN}'), '${MLPREFIX}libgtk-4.0')
  109. }